home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD023b.dsk / EDISON.bas < prev    next >
BASIC Source File  |  2003-06-12  |  14KB  |  264 lines
  1. 2  GOTO 100
  2. 4  ONERR  GOTO 7120
  3. 6  REM  <CTRL-M>=========================<CTRL-M><CTRL-M>TYPE "5" AND <RETURN> TO<CTRL-M>GET RID OF THE DUMB<CTRL-M>MISTAKE IN LINE 5!<CTRL-M><CTRL-M>=========================<CTRL-J>
  4. 100  TEXT : HOME : CLEAR 
  5. 110 Q$ =  CHR$(34):MF = 4541560: IF  PEEK( -1101) = 6  THEN PR = 1
  6. 120  REM <CTRL-M><CTRL-M>================<CTRL-M>  "CLOSE-ENUF"<CTRL-M><CTRL-M>BASED ON AN IDEA<CTRL-M>BY THOMAS EDISON<CTRL-M>================<CTRL-J>
  7. 130  REM <CTRL-M><CTRL-M>PAUL RAYMER<CTRL-M><CTRL-M>PAUL'S ELECTRIC COMPUTER<CTRL-M>3464 TOWNHOUSE DR<CTRL-M>LAS VEGAS NV 89121<CTRL-M><CTRL-M>
  8. 140  REM   IX/IX/MCMLXXXII<CTRL-J>
  9. 150  VTAB 3: PRINT Q$"CLOSE-ENUF...A NEW APPLE LANGUAGE";Q$
  10. 160  VTAB 5: HTAB 5: PRINT "1 - IF...MAYBE"
  11. 170  VTAB 7: HTAB 5: PRINT "2 - PRIMT"
  12. 180  VTAB 9: HTAB 5: PRINT "3 - GO NEAR"
  13. 190  VTAB 11: HTAB 5: PRINT "4 - LOST"
  14. 200  VTAB 13: HTAB 5: PRINT "5 - APPROX"
  15. 210  VTAB 15: HTAB 5: PRINT "6 - WALK"
  16. 220  VTAB 17: HTAB 5: PRINT "7 - ONERR...KEEP GOING"
  17. 230  VTAB 19: HTAB 5: PRINT "8 - SEARCH & DESTROY"
  18. 240  VTAB 21: HTAB 5: PRINT "9 - LEGAL RESTRICTIONS & EXIT"
  19. 250  VTAB 23: HTAB 1: PRINT "SELECT BY NUMBER ";: GET AN$:A =  VAL(AN$)
  20. 260  SPEED= 255
  21. 270  ON A GOTO 1000,2000,3000,4000,5000,6000,7000,8000,9000
  22. 1000  REM <CTRL-M><CTRL-M>========<CTRL-M>IF MAYBE<CTRL-M>========<CTRL-J>
  23. 1010  HOME 
  24. 1020  PRINT "EVERY ONCE IN A WHILE YOU MAY FIND THAT YOU CAN'T DECIDE IF YOU WANT TO DO      SOMETHING IF THE ANSWER IS (Y)ES OR (N)O": PRINT 
  25. 1030  FOR Z = 1 TO 1000: NEXT Z
  26. 1040  PRINT "OR IT MAY BE THAT YOU CAN'T DECIDE ON   SELECTING  (1) OR (2)  FROM A MENU...   OR YOU REALLY DON'T CARE.": PRINT 
  27. 1050  FOR Z = 1 TO 1000: NEXT Z
  28. 1060  PRINT : PRINT "IF...MAYBE  SOLVES THAT PROBLEM         =========="
  29. 1070  VTAB 20: HTAB 1: PRINT "PRESS A KEY TO CONTINUE ";: GET AN$
  30. 1080  HOME 
  31. 1090  SPEED= 255
  32. 1100  INPUT "ENTER VARIABLE #1 ";V1$
  33. 1110  INPUT "ENTER VARIABLE #2 ";V2$
  34. 1120  PRINT "WHAT DO YOU WANT TO HAPPEN IF ANYTHING  HAPPENS AT ALL?               ========": VTAB 4: HTAB 16: INPUT "";HAPPEN$
  35. 1130  HOME 
  36. 1140  VTAB 3: PRINT "100  IF ";V1$;" < = > ";V2$
  37. 1150  PRINT "110  THEN MAYBE A BELL WILL RING"
  38. 1160  PRINT "120  OR MAYBE PRINT ";Q$;HAPPEN$;Q$
  39. 1170  PRINT "130  END:REM  THIS IS SUGGESTED FORMAT
  40. 1180 X = 1
  41. 1190  VTAB 20: PRINT "PRESS <RETURN> TO START
  42. 1200  FOR Z = 1 TO 500: NEXT Z
  43. 1210  VTAB 20: PRINT "PRESS <SPACE > TO START"
  44. 1220  FOR Z = 1 TO 500: NEXT Z
  45. 1230 X = X +1: IF X = 7  THEN 1250
  46. 1240  GOTO 1190
  47. 1250  WAIT  -16384,128
  48. 1260 R =  INT(3 * RND(1)) +1
  49. 1270  IF R = 1  THEN  PRINT  CHR$(7): PRINT HAPPEN$
  50. 1280  IF R = 2  THEN  PRINT "NO BELL WILL RING"
  51. 1290  IF R = 3  THEN  PRINT "CAN'T DECIDE...TRY AGAIN?
  52. 1300  FOR Z = 1 TO 3000: NEXT Z
  53. 1301  POKE  -16368,0
  54. 1310  VTAB 20: HTAB 1: CALL  -958: INVERSE : PRINT " DID IT WORK? ";: NORMAL : GET AN$
  55. 1320  IF AN$ < >"Y"  THEN 1080
  56. 1330  GOTO 100
  57. 2000  REM  <CTRL-M><CTRL-M>=====<CTRL-M>PRIMT<CTRL-M>=====<CTRL-J>
  58. 2010  HOME 
  59. 2020  PRINT "TIRED OF SEEING (AND HEARING)": VTAB 3: HTAB 10: PRINT  CHR$(7);"? SYNTAX ERROR "
  60. 2030  VTAB 5: PRINT "WHEN YOU MAKE A TINY TYPING MISTEAK?": PRINT : PRINT "TYPE ANY WORD AT ALL WHICH STARTS WITH  A ";Q$;"P";Q$;", A SPACE, AND WHATEVER YOU WANT   TO PRIMT."
  61. 2040  SPEED= 255
  62. 2050  VTAB 10: PRINT L$
  63. 2060  PRINT  CHR$(93);: INPUT "";A$
  64. 2070  FOR X = 1 TO  LEN(A$)
  65. 2080 Z$ =  MID$ (A$,X,1)
  66. 2090  IF Z$ =  CHR$(32)  THEN W$ =  RIGHT$(A$, LEN(A$) -X): GOTO 2110
  67. 2100  NEXT X
  68. 2110  PRINT W$
  69. 2120  FOR Z = 1 TO 1000: NEXT Z
  70. 2130  VTAB 20: INVERSE : PRINT " DID IT WORK? ";: NORMAL : GET AN$
  71. 2140  IF AN$ < >"Y"  THEN 2000
  72. 2150  GOTO 100
  73. 3000  REM <CTRL-M><CTRL-M>=======<CTRL-M>GO NEAR<CTRL-M>=======<CTRL-J> 
  74. 3010  HOME 
  75. 3020  IF PR = 1  THEN  PRINT "One of the main faults with the Apple   and its present operating system is thatno latitude for indecision is permitted.": PRINT : GOTO 3040
  76. 3030  PRINT "ONE OF THE MAIN FAULTS WITH THE APPLE   AND ITS PRESENT OPERATING SYSTEM IS THATNO LATITUDE FOR INDECISION IS PERMITTED.": PRINT 
  77. 3040  IF PR = 1  THEN  PRINT "This makes it very awkward for the one  who is programming and is not sure to   which line to go next.": PRINT : GOTO 3060
  78. 3050  PRINT "THIS MAKES IT VERY AWKWARD FOR THE ONE  WHO IS PROGRAMMING AND IS NOT SURE TO   WHICH LINE TO GO NEXT.": PRINT 
  79. 3060  PRINT "GO NEAR  SOLVES THAT PROBLEM!           == ====": PRINT 
  80. 3070  VTAB 20: HTAB 1: PRINT "PRESS ALMOST ANY NUMBER TO CONTINUE ";: GET AN$: IF  VAL(AN$) <1  THEN  PRINT  CHR$(7); CHR$(7); CHR$(7);: VTAB 21: HTAB 18: PRINT "======": GOTO 3070
  81. 3080  HOME 
  82. 3090  PRINT "GRAPHIC DEMO FOLLOWS:": PRINT 
  83. 3100  INPUT "NAME OF ANY STATE? ";S$
  84. 3110  PRINT : SPEED= 76
  85. 3120  PRINT "100  INPUT ";Q$;"STATE? ";Q$;";ST$"
  86. 3130  PRINT "110  IF ST$ < THAN ALASKA GO NEAR 160"
  87. 3140  PRINT "120  IF ST$ = ALASKA THEN PRINT ";Q$;"WOW!";Q$
  88. 3150  PRINT "130  IF ST$ < ALASKA THEN PRINT ";Q$;"SMALL";Q$
  89. 3160  PRINT "140  IF ST$ > ALASKA THEN TELL WHOEVER       IS RUNNING THE PROGRAM HE OR SHE        IS TOTALLY UNINFORMED"
  90. 3170  SPEED= 255
  91. 3180  PRINT "150  REM"
  92. 3190  PRINT "160  REM"
  93. 3200  PRINT "170  REM"
  94. 3210  PRINT "180  REM"
  95. 3220  IF S$ = "ALASKA"  THEN  VTAB 15: HTAB 6: PRINT "ANSWER NEAR HERE?": FOR Z = 1 TO 1000: NEXT Z
  96. 3230  VTAB 14: HTAB 6: PRINT "ANSWER DUE SOON, HANG IN THERE": FOR Z = 1 TO 1000: NEXT Z
  97. 3240  VTAB 13: HTAB 6: PRINT "COMING UP WITH ANSWER SOON"
  98. 3250  FOR Z = 1 TO 2000: NEXT Z
  99. 3260 R =  INT(2 * RND(1)) +1
  100. 3270  IF R = 1  THEN  VTAB 15: HTAB 6: PRINT "LOOKING FOR LINE 160!": VTAB 16: HTAB 1: PRINT "190  ANSWER IS ";S$
  101. 3280  VTAB 16: HTAB 1: PRINT "190  ANSWER IS ";S$
  102. 3290  FOR X = 90 TO 60  STEP  -1
  103. 3300  VTAB 16: HTAB 2: PRINT X;: FOR Z = 1 TO 50: NEXT Z: NEXT X
  104. 3310  SPEED= 255
  105. 3320  VTAB 20: CALL  -958: INVERSE : PRINT " DID IT WORK? ";: NORMAL : GET AN$
  106. 3330  IF AN$ < >"Y"  THEN  HOME : GOTO 3080
  107. 3340  GOTO 100
  108. 4000  REM <CTRL-M><CTRL-M>====<CTRL-M>LOST<CTRL-M>====<CTRL-J>
  109. 4010  HOME 
  110. 4020  PRINT "WE ALL KNOW THAT THERE ARE SO MANY KEYS ON THE APPLE KEYBOARD IT IS AMAZING     THAT ANYTHING EVER GETS SPELLED RIGHT.": PRINT 
  111. 4030  PRINT "BECAUSE OF THIS FRAILTY OF THE          COMPUTER, THE ";Q$;"LOST";Q$;" ROUTINE IS NOW     PRESENTED.": PRINT 
  112. 4040  PRINT "TYPE ANYTHING YOU WANT...AFTER ALL, IT  IS YOUR COMPUTER, BUT WHEN YOU TYPE THE LETTER ";Q$;"L";Q$;" THE WORD ";Q$;"LIST";Q$;" WILL BE      SPELLED OUT FOR YOU ACCURATELY.": PRINT 
  113. 4050  FOR Z = 1 TO 2000: NEXT Z
  114. 4060  PRINT "EVENTUALLY.  ": FOR Z = 1 TO 1000: NEXT Z: PRINT 
  115. 4070  PRINT "THIS PORTION OF THE PROGRAM WILL THEN   LIST."
  116. 4080  VTAB 20: HTAB 1: PRINT "PRESS ALMOST ANY KEY TO CONTINUE ";: GET AN$
  117. 4090  HOME 
  118. 4100  VTAB 3: HTAB 1: PRINT  CHR$(93);: GET L$
  119. 4110  IF L$ < >"L"  THEN  PRINT  CHR$(7): GOTO 4100
  120. 4120  VTAB 3: HTAB 2: PRINT "L"
  121. 4130 R =  INT(26 * RND(1)) +65
  122. 4140  VTAB 3: HTAB 3: PRINT  CHR$(R)
  123. 4150  IF R < >73  THEN 4130
  124. 4160 R =  INT(26 * RND(1)) +65
  125. 4170  VTAB 3: HTAB 4: PRINT  CHR$(R)
  126. 4180  IF R < >83  THEN 4160
  127. 4190 R =  INT(26 * RND(1)) +65
  128. 4200  VTAB 3: HTAB 5: PRINT  CHR$(R)
  129. 4210  IF R < >84  THEN 4190
  130. 4220  LIST 4000,4090
  131. 4230  SPEED= 255
  132. 4240  VTAB 20: CALL  -958: INVERSE : PRINT " DID IT WORK? ";: NORMAL : GET AN$
  133. 4250  IF AN$ < >"Y"  THEN  HOME : GOTO 4090
  134. 4260  GOTO 100
  135. 4270  STOP 
  136. 5000  REM <CTRL-M><CTRL-M>=====<CTRL-M>APPROX<CTRL-M>======<CTRL-J> 
  137. 5010  HOME 
  138. 5020  PRINT "HAVE YOU EVER WONDERED WHY YOUR APPLE   HAS TO BE SO DARN"
  139. 5030  VTAB 2: HTAB 19: PRINT "PRECISE?"
  140. 5040  FOR Z = 1 TO 2000: NEXT Z
  141. 5050  INVERSE : VTAB 2: HTAB 19: PRINT "ACCURATE?": FLASH 
  142. 5060  FOR Z = 1 TO 2000: NEXT Z
  143. 5070  VTAB 2: HTAB 19: PRINT "PERSNICKETY?": NORMAL 
  144. 5080  FOR Z = 1 TO 2000: NEXT Z
  145. 5090  VTAB 2: HTAB 19: PRINT "PERSNICKETY?"
  146. 5100  PRINT : PRINT "WELL..."
  147. 5110  PRINT "NOW WE CAN GET EVEN!"
  148. 5120  FOR Z = 1 TO 2000: NEXT Z
  149. 5130  PRINT : PRINT "WE WILL NOW TRY A ";Q$;"FOR X = 1 TO APPROX  (NUMBER) LOOP.";Q$
  150. 5135  SPEED= 255
  151. 5140  PRINT : INPUT "START AT WHAT NUMBER? ";S
  152. 5150  PRINT : INPUT "END AT APPROX WHAT NUMBER? ";E
  153. 5160  HOME : PRINT "100  FOR X = ";S;" TO APPROX ";E
  154. 5170  PRINT "110  PRINT X"
  155. 5180 R =  INT(10 * RND(1)) +1
  156. 5190  IF  INT(R/2) = R/2  THEN E = E +R: GOTO 5210
  157. 5200 E = E -R
  158. 5210  SPEED= 100
  159. 5220  FOR X = S TO E
  160. 5230  INVERSE : PRINT X;" ";: NORMAL 
  161. 5240  NEXT X
  162. 5250  PRINT : PRINT "120  NEXT X"
  163. 5260  SPEED= 255
  164. 5270  VTAB 20: INVERSE : PRINT " DID IT WORK? ";: NORMAL : GET AN$
  165. 5280  IF AN$ < >"Y"  THEN  HOME : GOTO 5140
  166. 5290  GOTO 100
  167. 6000  REM <CTRL-M><CTRL-M>====<CTRL-M>WALK<CTRL-M>====<CTRL-J>
  168. 6010  HOME 
  169. 6020  PRINT "SOMETIMES IN THIS HURRY UP RUSH ABOUT   WORLD WE TRY TO GET TOO MANY THINGS DONETOO QUICKLY.": PRINT 
  170. 6030  PRINT "IF YOU HAVE NUMBER-CRUNCHING THINGS TO  DO -- FINE -- BUT FOR EVERYDAY STUFF... WHAT'S THE HURRY?": PRINT 
  171. 6040  PRINT "WALK  PROVIDES THE ANSWER               ===="
  172. 6050  VTAB 20: HTAB 1: PRINT "PRESS ANY KEY TO CONTINUE";: FOR Z = 1 TO 2000: NEXT Z: PRINT " IF YOU WISH ";: GET AN$
  173. 6060  HOME 
  174. 6070  VTAB 7: HTAB 5: PRINT "(1) WALK -- LEISURELY PACE"
  175. 6080  VTAB 9: HTAB 5: PRINT "(2) RUN -- BACK TO RAT RACE"
  176. 6090  VTAB 12: HTAB 2: PRINT "SELECT BY NUMBER ";: GET AN$
  177. 6100  IF AN$ = "1"  THEN  SPEED= 50: GOTO 6200
  178. 6110  SPEED= 255
  179. 6200  GOTO 100
  180. 7000  REM  <CTRL-M><CTRL-M>================<CTRL-M>ONERR KEEP GOING<CTRL-M>================<CTRL-J>
  181. 7010  HOME 
  182. 7015  IF PR = 1  THEN  PRINT "Don't you think that after you spend a  thousand bucks on a computer you ought  to get one which doesn't care if you    make a mistake or two?": GOTO 7030
  183. 7020  PRINT "DON'T YOU THINK THAT AFTER YOU SPEND A  THOUSAND BUCKS ON A COMPUTER YOU OUGHT  TO GET ONE WHICH DOESN'T CARE IF YOU    MAKE A MISTAKE OR TWO?"
  184. 7030  PRINT : PRINT "SO DO WE!"
  185. 7040  FOR Z = 1 TO 1000: NEXT Z
  186. 7050  PRINT : PRINT "TYPE THE LINE NUMBER (5) AND THEN       ANYTHING YOU WANT, LIKE --": PRINT : PRINT "5  X = 100 /  0"
  187. 7060  PRINT : PRINT "AND THEN...TYPE ";Q$;"RUN 4";Q$
  188. 7070  END 
  189. 7080  ONERR  GOTO 7120
  190. 7090  VTAB 20: INVERSE : PRINT " DID IT WORK? ";: NORMAL : GET AN$
  191. 7100  IF AN$ < >"Y"  THEN  HOME : GOTO 7000
  192. 7110  GOTO 100
  193. 7120  HOME : PRINT  CHR$(7);"YOU JUST COMMITTED STUPID ERROR NUMBER "
  194. 7130  SPEED= 200: FOR X = 1 TO 100: PRINT  PEEK(222); CHR$(32);: NEXT X
  195. 7140  PRINT "BUT I FORGIVE YOU!": SPEED= 255
  196. 7160  GOTO 7090
  197. 7170  GOTO 100
  198. 8000  REM  <CTRL-M><CTRL-M>================<CTRL-M>SEARCH & DESTROY<CTRL-M>================<CTRL-J>
  199. 8010  HOME 
  200. 8020  PRINT "THE USE OF ";Q$;"PEEK";Q$;" AND ";Q$;"POKE";Q$" ARE VERY   LIKELY THE MOST OVER-RATED COMMANDS IN  THE WHOLE BASIC LANGUAGE.": PRINT 
  201. 8030  PRINT "FIND THINGS BY ";Q$;"PEEKING";Q$;"!  BIG DEAL!    OF COURSE THAT'S HOW YOU USUALLY FIND   THINGS.": PRINT 
  202. 8040  PRINT "AND ";Q$;"POKING";Q$;".  (HA-HA).": PRINT 
  203. 8050  PRINT "A NEW ELEMENT OF ELECTRIC EXCITEMENT IS INTRODUCED WITH ";Q$;"SEARCH AND DESTROY";Q$;".": PRINT 
  204. 8060  PRINT "YOU PICK ANY TARGET YOU WISH -- AND ZAP IT RIGHT OUT OF YOUR COMPUTER!.  NOW    THAT IS TRULY EDUCATIONAL PROGRAMMING.  ----": PRINT 
  205. 8070  VTAB 20: HTAB 1: PRINT "=== PRESS Z (FOR ZAP) TO CONTINUE === ";: GET AN$
  206. 8080  IF AN$ < >"Z"  THEN 8070
  207. 8090  HOME 
  208. 8100  PRINT "SEARCH & DESTROY DEMONSTRATION": PRINT 
  209. 8110  PRINT "TYPE ANY LETTER ";: GET L$: PRINT 
  210. 8120  VTAB 3: HTAB 20: PRINT "THANK YOU!"
  211. 8130  PRINT : PRINT "YOUR COMPUTER WILL NOW PLACE THE LETTER": PRINT Q$;L$;Q$;" AT RANDOM ON THE SCREEN": VTAB 20: HTAB 1: PRINT "PRESS SPACE BAR TO CONTINUE ";: GET AN$
  212. 8140 H =  INT(37 * RND(1)) +1
  213. 8150 V =  INT(19 * RND(1)) +1
  214. 8160  VTAB V: HTAB H: PRINT Q$;L$;Q$
  215. 8170  VTAB 20: HTAB 1: PRINT "NOW THAT THE LITTLE DEVIL IS IN PLACE": FOR Z = 1 TO 2000: NEXT Z
  216. 8180  VTAB 20: HTAB 1: PRINT "THE SEARCH & DESTROY WILL LOCATE IT AND": FOR Z = 1 TO 2000: NEXT Z
  217. 8190  VTAB 20: HTAB 1: CALL  -868: PRINT "ZAP IT (AND ALL ";L$;"'S) OUT OF YOUR": PRINT "SYSTEM FOREVER!": FOR Z = 1 TO 2000: NEXT Z
  218. 8200  FOR X = 1024 TO 2038
  219. 8210  IF  PEEK(X) =  ASC(L$) +128  THEN  POKE X, ASC(L$): GOTO 8230
  220. 8220  POKE X,174
  221. 8230  NEXT X
  222. 8240  FOR X = 2039 TO 1024  STEP  -1
  223. 8250  IF  PEEK(X) =  ASC(L$)  THEN  PRINT  CHR$(7);: POKE X,170: GOTO 8270
  224. 8260  POKE X,160
  225. 8270  NEXT X
  226. 8280  FOR X = 1024 TO 2039: POKE X,160: NEXT X
  227. 8290  VTAB 3: HTAB 1: PRINT "LET'S TRY YOUR COMPUTER NOW...": PRINT "TYPE SEVERAL WORDS WITH THE LETTER      YOU JUST ZAPPED..."
  228. 8300  PRINT 
  229. 8310  GET W$
  230. 8320  IF W$ =  CHR$(13)  THEN 8360
  231. 8330  IF W$ = L$  THEN  PRINT "?";: GOTO 8310
  232. 8340  PRINT W$;
  233. 8350  GOTO 8310
  234. 8360  PRINT 
  235. 8370  SPEED= 255
  236. 8375 WS$ = " DID IT WORK? "
  237. 8380  PRINT : VTAB 20: HTAB 1: INVERSE 
  238. 8381  FOR XX = 1 TO 14
  239. 8382  IF  MID$ (WS$,XX,1) = L$  THEN  PRINT "?";: GOTO 8384
  240. 8383  PRINT  MID$ (WS$,XX,1);
  241. 8384  NEXT XX
  242. 8385  NORMAL 
  243. 8386  GET AN$
  244. 8390  IF AN$ < >"Y"  THEN  HOME : GOTO 8090
  245. 8400  GOTO 100
  246. 9000  REM  <CTRL-M><CTRL-M>=====<CTRL-M>LEGAL<CTRL-M>=====<CTRL-J> 
  247. 9010  HOME 
  248. 9020  IF PR = 1  THEN  PRINT "This program should not be used in      conjunction with any program using      Pascal, Cobal, LOGO, CP/M, USDA or      electricity.": PRINT : GOTO 9040
  249. 9030  PRINT "THIS PROGRAM SHOULD NOT BE USED IN      CONJUNCTION WITH ANY PROGRAM USING      PASCAL, COBAL, LOGO, CP/M, USDA OR      ELECTRICITY.": PRINT 
  250. 9040  IF PR = 1  THEN  PRINT "Use of this new language is confined to the purchaser of this program, members  of his/her computer group and his/her   close friends.": PRINT : GOTO 9060
  251. 9050  PRINT "USE OF THIS NEW LANGUAGE IS CONFINED TO THE PURCHASER OF THIS PROGRAM, MEMBERS  OF HIS/HER COMPUTER GROUP AND HIS/HER   CLOSE FRIENDS.": PRINT 
  252. 9060  FOR Z = 1 TO 3000: NEXT Z
  253. 9070  IF PR = 1  THEN  PRINT "Certain relatives, neighbors, pen-pals  and computer store owners, operators,   magazine publishers, schools and radio  and TV stations.": GOTO 9090
  254. 9080  PRINT "CERTAIN RELATIVES, NEIGHBORS, PEN-PALS  AND COMPUTER STORE OWNERS, OPERATORS,   MAGAZINE PUBLISHERS, SCHOOLS AND RADIO  AND TV STATIONS."
  255. 9090  FOR Z = 1 TO 3000: NEXT Z
  256. 9100  PRINT : INVERSE : PRINT "ANY UNAUTHORIZED PERSONS USING THIS     PROGRAM WILL BE PERSECUTED AND VIOLATED.": NORMAL 
  257. 9110  FOR Z = 1 TO 2000: NEXT Z
  258. 9120  PRINT : PRINT "HAVE A NICE DAY!"
  259. 9130  FOR Z = 1 TO 5000: NEXT Z
  260. 9140  HOME 
  261. 9150  VTAB 20: PRINT "TO RESUME PROGRAM...TYPE RUN"
  262. 9160  SPEED= 255
  263. 9165  PRINT : PRINT "TO RETURN TO SOFTDISK... TYPE RUN MENU"
  264. 9170  VTAB 1: HTAB 1: LIST 6